Logo des digitalen Schulbuchs inf-schule.de. Schriftzug in Zustandsübergangsdiagramm eines endlichen Automaten.

Minimallogo des digitalen Schulbuchs inf-schule.de. Schriftzug in Zustandsübergangsdiagramm eines endlichen Automaten.

s n h m r u
i

Projekt Smartphone-Ständer

Ständer für ein schräg stehendes Smartphone[1]

Damit ein Smartphone seinen Platz auf dem Schreibtisch findet, kann ein Ständer eine Hilfe sein. Dabei soll es auch in aufrechter Position geladen werden können. Das Ladekabel wird dafür nach hinten weggeführt. Gummi-Pads auf der Unterseite sorgen für Rutschfestigkeit - dafür werden Vertiefungen benötigt.
Betrachte das 3D-Modell im Viewer:

Aufgabe 1: Die Bodenplatte

Entwirf deine eigene Bodenplatte in OpenSCAD.

Bestimme zunächst die Maße deines Smartphones (Höhe, Breite, Tiefe).

Die Platte im obigen Beispiel hat folgende Eigenschaften:

  • die Höhe der Bodenplatte ist 4mm
  • der Grundkörper ist ein quadratischer Quader (Kantenlänge 70mm) mit zwei aufgesetzten Kreisen (Radius 5mm) und zwischenliegendem Quader (s. Skizze)
  • aus dem Grundkörper wurde eine verkleinerte Version (30mm) der identischen Bodenplatte ausgeschnitten (dies bringt jedoch kaum Vorteile beim Druck, da liegend gedruckt wird und hierfür letzten Endes Stützen benötigt werden (s.u.))
  • für die Gummi-Pads der Dicke 2mm gibt es passende Vertiefungen (aber nur 1,5mm tief)
Schematische Zeichnung der Bodenplatte[2]

Das Modul "platte" wird auch für die Schräge noch benötigt...

module platte(x,y,z,radius){
    //Platte
    cube([x,y,z]);
    //Abrundungen oben
    translate([radius,y,0])cylinder(h=z,r=radius); 
    translate([x-radius,y,0])cylinder(h=z,r=radius);
    translate([radius,y,0])cube([x-2*radius,radius,z]);
}

difference(){
    platte(70,70,4,5);
    translate([20,20,0])platte(30,30,4,5); //Loch in Bodenplatte
    translate([5,5,0])cube([10,10,1.5]); //4 Vertiefungen für Gummi-Pads
    translate([5,70-10,0])cube([10,10,1.5]); 
    translate([70-15,5,0])cube([10,10,1.5]); 
    translate([70-15,70-10,0])cube([10,10,1.5]); 
}

Aufgabe 2: Die Schräge

Erzeuge eine Schräge mit Auflagen für dein Smartphone nach deinen Vorstellungen.

Eigentlich benötigen wir jetzt erneut das Gleiche - nur dass wir abschließend die Platte in einem Winkel von 70° aufrecht stellen.

Kommentiere zunächst wieder die Bodenplatte aus (/*...*/), damit du dich voll auf die neue Platte konzentrieren kannst.

Es ist sinnvoll, zunächst die komplette Platte liegend zu konstruieren und erst im Anschluss das gesamte Objekt in den passenden Winkel aufzurichten. Das ist wesentlich einfacher...

1. Schritt: Platte mit Halter

Wenn du weißt, wie dick dein Smartphone ist, dann achte darauf, dass der Haltebereich, auf dem das Smartphone letzten Endes steht, etwas größer ist, so dass das Smartphone genügend "Spiel" hat, um leicht reinzupassen.

Gruppieren
  1. Wir verwenden wieder die gleich Art von Platte wie für den Boden - diese ist nur etwas länger (100mm)
  2. Die Stelle, auf der das Smartphone steht, sollte weit genug in positiver y-Richtung (z.B. 30mm) sein, damit nach dem Aufrichten das Ladekabel unterhalb Platz genug hat.
  3. Nun benötigen wir noch einen Schutz, damit das Smartphone nicht nach vorne kippt.

Klicke auf die einzelnen Schritte zur Veranschaulichung.

//schraege();
platte(70,100,4,5);
translate([0,30,4])cube([70,4,12]); //12mm: Damit hat das Smartphone genügend Platz
translate([0,30,4+12])cube([70,4+6,4]);//6mm: Damit kippt es nicht mehr nach vorne

2. Schritt: Löcher bohren

Wir benötigen auf jeden Fall eine Durchführung für das Kabel.
Du kannst aber auch noch weitere Löcher in die Schräge bohren, um sie nach deinen Vorstellungen zu gestalten

Dafür vereinigen wir die Elemente aus dem 1. Schritt (mit union()) und subtrahieren davon (mit difference()) die entsprechenden Körper.

Gruppieren
  1. Wir starten mit dem Ergebnis aus dem 1. Schritt
  2. Nun nehmen wir erneut die Platte vom Anfang in einer deutlich stärkeren Dicke und kleiner, doch...
  3. ... anstatt sie hinzuzufügen, wird sie subtrahiert.
  4. Es könnte nun eine Reihe von Prismen ausgestochen werden.
  5. Die nächste Reihe etwas versetzt.
  6. Und das Ganze noch einmal...

Klicke auf die einzelnen Schritte zur Veranschaulichung.

difference(){
    union(){
        platte(70,100,4,5);
        translate([0,30,4])cube([70,4,12]); //12mm: Damit hat das Smartphone genügend Platz
        translate([0,30,4+12])cube([70,4+6,4]);//6mm: Damit kippt es nicht mehr nach vorne
    }
    //Kabeldurchführung
    translate([(70-26)/2,6,0])platte(26,34,30,2); 
    //Bohrungen
    for (i=[0:3])translate([10+i*17,55,0])cylinder(5,5,5,$fn=6);
    for (i=[0:2])translate([18.5+i*17,55+14,0])cylinder(5,5,5,$fn=6);
    for (i=[0:3])translate([10+i*17,55+2*14,0])cylinder(5,5,5,$fn=6);
    for (i=[0:2])translate([18.5+i*17,55+3*14,0])cylinder(5,5,5,$fn=6); 
}

3. Schritt: Aufrichten

Nun richten wir die Schräge im Winkel von 70° auf.

Gruppieren
  1. Das Ergebnis des 2. Schritts
  2. ... wird um 70° um die x-Achse gedreht ...
  3. ... und um 1,5mm nach unten verschoben, damit wir eine saubere Kante erhalten.
  4. Das, was im negativen z-Bereich übersteht, wird abgeschnitten.
  5. Jetzt können wir auch die Bodenplatte wieder sichtbar machen.
  6. Nach dem Rendern sind auch die Löcher zu sehen.

Klicke auf die einzelnen Schritte zur Veranschaulichung.

module platte(x,y,z,radius){
    //Platte
    cube([x,y,z]);
    //Abrundungen oben
    translate([radius,y,0])cylinder(h=z,r=radius); 
    translate([x-radius,y,0])cylinder(h=z,r=radius);
    translate([radius,y,0])cube([x-2*radius,radius,z]);
}

module schraege(){
    difference(){
        union(){
            platte(70,100,4,5);
            translate([0,30,4])cube([70,4,12]); //12mm: Damit hat das Smartphone genügend Platz
            translate([0,30,4+12])cube([70,4+6,4]);//6mm: Damit kippt es nicht mehr nach vorne
        }
        //Kabeldurchführung
        translate([(70-26)/2,6,0])platte(26,34,30,2); 
        //Bohrungen
        for (i=[0:3])translate([10+i*17,55,0])cylinder(5,5,5,$fn=6);
        for (i=[0:2])translate([18.5+i*17,55+14,0])cylinder(5,5,5,$fn=6);
        for (i=[0:3])translate([10+i*17,55+2*14,0])cylinder(5,5,5,$fn=6);
        for (i=[0:2])translate([18.5+i*17,55+3*14,0])cylinder(5,5,5,$fn=6); 
    }
}
 
// die Bodenplatte
difference(){
    platte(70,70,4,5);
    translate([20,20,0])platte(30,30,4,5); //Loch in Bodenplatte
    translate([5,5,0])cube([10,10,1.5]); //4 Vertiefungen für Filzgleiter
    translate([5,70-10,0])cube([10,10,1.5]); 
    translate([70-15,5,0])cube([10,10,1.5]); 
    translate([70-15,70-10,0])cube([10,10,1.5]); 
}
//die Schräge
difference(){
    translate([0,0,-1.5])rotate([70,0,0])schraege();
    translate([0,-10,-10])cube([70,20,10]);
}

Der Druck

Egal, wie man das Modell dreht: Es werden Stützen benötigt.

Ständer auf Druckbett seitlich liegend mit Stützen[3]

Es ist sehr zu empfehlen, das Modell im Slicer auf die Seite zu drehen. Fällt ein Grund dafür ein?

1. Grund: Es werden weniger Stützen benötigt.

2. Grund: Die Qualtität der Verbindung zwischen Bodenplatte und Schräge ist erheblich stabiler.
Der Drucker fährt in jeder Schicht die Stoßkante zwischen Bodenplatte und Schräge in einem Zug durch.

Achtung Verletzungsgefahr!
Entferne die Stützen hinterher vorsichtig mit leichter Gewalt mit einer Flachzange.
Das spröde PLA fliegt dabei aber teilweise unkontrolliert durch die Luft.
Trage deshalb beim Entfernen der Stützen Handschuhe und eine Schutzbrille!
Ständer aufrecht stehend ohne Stützen[4]

Quellen

Suche

v
14.2.4.5
www.inf-schule.de/projekte/3d_druck/projekte/smartphonestaender
www.inf-schule.de/14.2.4.5

Rückmeldung geben