i

Projekt Schlüsselanhänger

Extrudierte Ellipse mit inf-schule Beschriftung[1]

Der Schlüsselanhänger ist relativ flach (2mm). Er soll ab 1,5mm Höhe in einer zweiten Farbe ausgedruckt werden - dafür benötigt er eine entsprechende erhöhte Struktur in z-Richtung.

Aufgabe

Modelliere einen Schlüsselanhänger mit OpenSCAD nach deinen Vorstellungen. Allerdings gibt es folgende Rahmenbedingungen:

  • Höhe: 2mm
  • Max. Länge: 10 cm (das ist für einen Schlüsselbund eigentlich schon zuviel)
  • Max. Breite: 2,5 cm
  • Farbwechsel in der Höhe von 1,5mm ermöglichen (damit es zu keinen Fehlern kommt, sollte im Slicer der Farbwechsel erst bei 1,6mm oder höher stattfinden)
  • Loch an einem Ende, so dass er an den Schlüsselring anzubringen ist.
  • Der Schlüsselanhänger soll Muster enthalten (oben sind es die Punkte), die durch eine Wiederhole-Anweisung entstanden sind.

Eine mögliche Vorlage


$fa = 1;
$fs = 0.4;

/* Die Punkte werden zweimal verwendet - deshalb hier als neues Modul.
Sie liegen auf einer angepassten Potenzfunktion vierten
Grades (i*i*i*i=i^4)(ab Version 2021.01 von OpenSCAD kann direkt i^4 geschrieben werden). 
Die Punkte werden im Schleifendurchlauf durch das "resize" größer.
*/
module punkte() {for (i=[1:6]) translate([13+i*2.9,-5+0.005*i*i*i*i,0])resize([0.5*i, 0.5*i, 0.5]) cylinder(.5,1,1);}

//Blaue Bodenplatte (Höhe 1,5mm) mit Loch für Schlüsselring und Musterlöchern
color("#0077b6")difference(){
	//Bodenplatte
    resize([80,20,1.5])cylinder(1,20,20);
	//Loch für Schlüsselring
    translate([-35,0,-1])cylinder(4,2,2);
	//Ausgestanzte Punkte
    translate([0,0,-1])scale([1,1,8])punkte();
}

//Auf die Bodenplatte: Schriftzug, Außenring und Musterpunkte 
//Tipp:Für die Vorschau: z-Wert 1.51 statt 1.5 wählen
color("#fcca00")translate([0,0,1.5])
union(){
    //Schriftzug
    linear_extrude(0.5)text(text="inf-schule.de", font = "Rockwell:style=Normal", size=6, halign="center", valign="center");
    //Außenring
    difference(){
        resize([80,20,0.5])cylinder(.5,20,20);
        translate([0,0,-1])resize([76,16,3])cylinder(3,20,20);
    }    
    //Aufliegende Punkte
    rotate([0,0,180]) punkte();
}

Das Druckergebnis

Extrudierte Ellipse mit inf-schule Beschriftung unten schwarz oben rot[2]

Vergleiche das Druckergebnis mit der Planung oben. Fällt dir etwas auf?

Es fehlt jeweils der kleinste Punkt. Dieser hat im Modell die Größe 0,5mm und kann (zumindest bei der Standard-Düsenbreite von 0,4mm) nicht dargestellt und ein entsprechendes Loch nicht erzeugt werden.

Wenn du auf das Bild klickst, wird es dir größer angezeigt. Dann siehst du auch, dass die Spuren des Extruders bei den roten Punkten. Hier müsste man noch detaillierter slicen und möglichst eine feinere Düse verwenden - das geht aber deutlich zu Lasten der Zeit,

Quellen

Suche

v
14.2.4.3
www.inf-schule.de/projekte/3d_druck/projekte/schluesselanhaenger
www.inf-schule.de/14.2.4.3

Rückmeldung geben